CheckExternalScripts: check_updates_available.vbs

'########################################################################
'# Name: Michel van Son (michelvs@phison.nl)                                                    #
'# Company: Phison Technologies                                                                                 #
'# Date: 21-02-2011                                                                                                             #
'# Purpose: External check script to check if updates are available             #
'# Changes: [dd-mm-yyyy] Name | changes                                                                 #
'########################################################################

'################################################################################################################
'# Without an argument, this script will return the amount of available updates with exit code 0                                #
'# When supplying arguments, the first argument is the warning treshold and the second is the critical treshold #
'# More or less then 2 arguments will result in an error with status Unknown(3)                                                                 #
'################################################################################################################

Option Explicit

'Declare variables.
Dim valWarning
Dim valCritical
Dim objWMIService
Dim valUpdates
Dim updateSession
Dim updateSearcher
Dim searchResult
Dim I


'Check for arguments.
if Wscript.Arguments.Count > 0 then
        if Wscript.Arguments.Count > 2 then
                Wscript.Echo "Too many arguments given. Please enter warning and critical tresholds."
                Wscript.Quit(3)
        elseif Wscript.Arguments.Count < 2 then
                Wscript.Echo "Too few arguments given. Please enter warning and critical tresholds."
                Wscript.Quit(3)
        else
                valWarning = Wscript.Arguments.Item(0)
                valCritical = Wscript.Arguments.Item(1)
                valWarning = CInt(valWarning)
                valCritical = CInt(valCritical)
        end if
end if

'Start searching for updates
Set updateSession = CreateObject("Microsoft.Update.Session")
Set updateSearcher = updateSession.CreateupdateSearcher()
Set searchResult = updateSearcher.Search("IsInstalled=0 and Type='Software'")

valUpdates = searchResult.Updates.count - 1

'Check the updates count, echo it and exit with proper exitcode.
if valUpdates > 0 then
        if Not IsEmpty(valCritical) then
                if valUpdates >= valCritical then
                        Wscript.Echo "Critical: applicable updates: " & valUpdates & "|'Updates'=" & valUpdates & ";" & valWarning & ";" & valCritical
                        Wscript.Quit(2)
                elseif valUpdates >= valWarning then
                        Wscript.Echo "Warning: applicable updates: " & valUpdates & "|'Updates'=" & valUpdates & ";" & valWarning & ";" & valCritical
                        Wscript.Quit(1)
                else
                        Wscript.Echo "OK: applicable updates: " & valUpdates & "|'Updates'=" & valUpdates & ";" & valWarning & ";" & valCritical
                        Wscript.Quit(0)
                end if
        else
                Wscript.Echo "OK: applicable updates: " & valUpdates & "|'Updates'=" & valUpdates
                Wscript.Quit(0)
        end if
else
        Wscript.Echo "OK: No applicable updates.|'updates'=" & valUpdates
        Wscript.Quit(0)
end if